Arduino Leonardo

#include <Keyboard.h>

const int BUTTON = 8;
char shiftKey = KEY_LEFT_SHIFT;

void setup() {
  pinMode(BUTTON, INPUT_PULLUP); // 内部プルアップ抵抗を有効にして入力
  Keyboard.begin();
}

void loop() {
  if (digitalRead(BUTTON) == LOW) {
    /* 記号は正しく出力されない事がある */

    Keyboard.println("program TEST;");
    Keyboard.println("");

    // {
    Keyboard.press(shiftKey);
    Keyboard.press(']');
    delay(100);
    Keyboard.releaseAll();

    Keyboard.print("$APPTYPE CONSOLE");

    // }
    Keyboard.press(shiftKey);
    Keyboard.press(0x5c);
    delay(100);
    Keyboard.releaseAll();

    Keyboard.println("");
    Keyboard.println("");
    Keyboard.println("begin");
    Keyboard.print("  writeln");

    // (
    Keyboard.press(shiftKey);
    Keyboard.press('8');
    delay(100);
    Keyboard.releaseAll();

    // '
    Keyboard.press(shiftKey);
    Keyboard.press('7');
    delay(100);
    Keyboard.releaseAll();

    // Hello, world.
    Keyboard.print("Hello, world.");

    // '
    Keyboard.press(shiftKey);
    Keyboard.press('7');
    delay(100);
    Keyboard.releaseAll();

    // )
    Keyboard.press(shiftKey);
    Keyboard.press('9');
    delay(100);
    Keyboard.releaseAll();

    // ;
    Keyboard.println(";");

    Keyboard.println("end.");
    delay(500);
  }  
}

#include <Mouse.h>
#include <LiquidCrystal.h>

const int NUM_KEYS = 5;
const int DIST = 8;
char msgs[NUM_KEYS][17] = 
                   {"Mouse: Right",
                    "Mouse: Up   ",
                    "Mouse: Down ",
                    "Mouse: Left ",
                    "Click       "};
int adc_key_val[NUM_KEYS] ={70, 240, 420, 620, 880};
int adc_key_in;
int key = -1;

LiquidCrystal lcd(8, 9, 4, 5, 6, 7);

void setup() {
  lcd.begin(16, 2);
  lcd.clear();
  Mouse.begin();
}

void loop() {
  adc_key_in = analogRead(0);
  key = get_key(adc_key_in);
  if (key < 0)
    return;
  lcd.setCursor(0, 0);
  lcd.print(msgs[key]);
  switch (key) {
   case 0:
     Mouse.move(DIST, 0, 0);
     break;         
   case 1:
     Mouse.move(0, -DIST, 0);
     break;         
   case 2:
     Mouse.move(0, DIST, 0);
     break;         
   case 3:
     Mouse.move(-DIST, 0, 0);
     break;         
   case 4:
     Mouse.click();
     break;         
  }
  if (key <= 3)
    delay(50);
  else
    delay(500);
  lcd.clear();
}

int get_key(unsigned int input)
{
  int k;
  for (k = 0; k < NUM_KEYS; k++)
    if (input < adc_key_val[k])
      return k;
  if (k >= NUM_KEYS)
    k = -1;
  return k;
}

#include <Joystick.h>

Joystick_ Joystick;

/* GENERAL */
const int ARROW_MIN = 0;
const int ARROW_MAX = 1023;
const int ARROW_NEUTRAL = ARROW_MAX / 2;
const int BUTTON_UP = 0;
const int BUTTON_DOWN = 1;
const int BUTTON_LEFT = 2;
const int BUTTON_RIGHT = 3;

/* ARROWS */
const int NUM_OF_ARROWS = 4;
const int PIN_UP = A0;
const int PIN_DOWN = A3;
const int PIN_LEFT = A2;
const int PIN_RIGHT = A1;

const int ArrowPin[NUM_OF_ARROWS] = {PIN_UP, PIN_DOWN, PIN_LEFT, PIN_RIGHT};
int lastArrowState[NUM_OF_ARROWS] = {0, 0, 0, 0};

/* BUTTONS */
const int NUM_OF_BUTTONS = 2;
const int PIN_A = 7;
const int PIN_B = 8;

const int ButtonPin[NUM_OF_BUTTONS] = {PIN_A, PIN_B};
int lastButtonState[NUM_OF_BUTTONS] = {0, 0};

void setup() {
  for (int index = 0; index < NUM_OF_ARROWS; index++)
    pinMode(ArrowPin[index], INPUT_PULLUP);
  for (int index = 0; index < NUM_OF_BUTTONS; index++)
    pinMode(ButtonPin[index], INPUT_PULLUP);
  Joystick.begin();
  Joystick.setXAxis(ARROW_NEUTRAL);
  Joystick.setYAxis(ARROW_NEUTRAL);
  Joystick.setZAxis(ARROW_NEUTRAL);
}

void loop() {
  /* ARROWS */
  for (int index = 0; index < NUM_OF_ARROWS; index++)
    lastArrowState[index] = !digitalRead(ArrowPin[index]);
  if (lastArrowState[BUTTON_UP] == lastArrowState[BUTTON_DOWN])
    Joystick.setYAxis(ARROW_NEUTRAL);
  else
    Joystick.setYAxis((lastArrowState[BUTTON_UP]) ? ARROW_MIN : ARROW_MAX); 
  if (lastArrowState[BUTTON_LEFT] == lastArrowState[BUTTON_RIGHT])
    Joystick.setXAxis(ARROW_NEUTRAL);
  else
    Joystick.setXAxis((lastArrowState[BUTTON_LEFT]) ? ARROW_MIN : ARROW_MAX); 

  /* BUTTONS */
  for (int index = 0; index < NUM_OF_BUTTONS; index++)
  {
    int currentButtonState = !digitalRead(ButtonPin[index]);
    if (currentButtonState != lastButtonState[index])
    {
      Joystick.setButton(index, currentButtonState);
      lastButtonState[index] = currentButtonState;
    }
  }
  delay(10);  
}