<!-- https://github.com/oscarmorrison/md-page -->
<script src="/md-page/md-page.js"></script><noscript>
<head>
<title>Delphi のインライン変数宣言と配列</title>
</head>
# Delphi のインライン変数宣言と配列

---

tags: Delphi programming embarcadero objectpascal
created_at: 2019-02-04
updated_at: 2019-04-10

---
# はじめに
Delphi 10.3 Rio でインライン変数宣言とその型推論が実装されたのですが、試していたら配列が宣言できない事に気付きました。どうにか配列をインライン変数宣言できないものか試してみます。

 - [インライン変数宣言 (DocWiki)](http://docwiki.embarcadero.com/RADStudio/ja/%E3%82%A4%E3%83%B3%E3%83%A9%E3%82%A4%E3%83%B3%E5%A4%89%E6%95%B0%E5%AE%A3%E8%A8%80)
 - [配列型 (DocWiki)](http://docwiki.embarcadero.com/RADStudio/ja/%E6%A7%8B%E9%80%A0%E5%8C%96%E5%9E%8B%EF%BC%88Delphi%EF%BC%89#.E9.85.8D.E5.88.97.E5.9E.8B)

インライン変数宣言と型推論に関する記事は以前にも幾つか書いています。

 - [Delphi 10.3 Rio で CSV を処理する (Qiita)](./2802677fe1cfaa4d1332.md)
 - [Delphi とラムダ式とクロージャ (Qiita)](./bd33a26bec9e4cf25a8d.md)

# 問題のコード
**var** ブロックであれば静的配列は以下のように宣言できます。

```pascal:
procedure Test;
var
  arr: array [0..9] of Integer;
begin

  ...

end;
```
これを **var** キーワードを使ってインライン変数宣言してみると、

```pascal:
procedure Test;
begin
  var arr: array [0..9] of Integer;
  ...

end;
```

これが通らないのです。

```pascal:
procedure Test;
begin
  var arr: array of Integer;
  ...

end;
```

動的配列もダメです。


## 不思議な記述
何故か型推論を使うと以下のような(動的)配列の宣言が可能です。

```pascal:
procedure Test;
begin
  var arr := [512, 1024]; // array of Integer
  ...

end;
```
値が 255 を超えても OK (集合ではない) ですし、

```pascal:
procedure Test;
begin
  var arr := [512, 1024]; // array of Integer
  arr[0] := 2048; // 代入
  ...

end;
```
代入も可能です。そしてこれは動的配列扱いなので、配列の拡張も可能です。

```pascal:
procedure Test;
begin
  var arr := [512, 1024]; // array of Integer
  SetLength(arr, 10); // 配列の拡張
  ...

end;
```

但し、空の動的配列は宣言できません。

```pascal:
procedure Test;
begin
  var arr := []; // NG
  ...

end;
```

これの何が `不思議な記述` なのかと言うと、Delphi では配列がローカル変数でなければ宣言と同時に初期値を代入できるのですが、

```pascal:
var
  Nums: array [0..2] of Integer = (1, 2, 3);
```

だったら、さっきのも

```pascal:
procedure Test;
begin
  var arr := (512, 1024); // array of Integer
  ...

end;
```
() を使った方が自然じゃないのかと思うわけです。何故 [] にしたのでしょうね？

## 動的配列の文字列風の操作

...と、不思議に思って調べていたら XE7 で動的配列の操作に新機能が追加されていました。

```pascal:
var
  A: array of integer;
  B: TBytes = [1, 2, 3, 4]; //Initialization can be done from declaration
begin
  ...
  A := [1, 2, 3];  // assignation using constant array
  A := A + [4, 5]; // addition - A will become [1,2,3,4,5]
  ...
end;
```
 - [動的配列に対する文字列風の操作をサポート (DocWiki)](http://docwiki.embarcadero.com/RADStudio/Rio/ja/%E6%A7%8B%E9%80%A0%E5%8C%96%E5%9E%8B%EF%BC%88Delphi%EF%BC%89#.E5.8B.95.E7.9A.84.E9.85.8D.E5.88.97.E3.81.AB.E5.AF.BE.E3.81.99.E3.82.8B.E6.96.87.E5.AD.97.E5.88.97.E9.A2.A8.E3.81.AE.E6.93.8D.E4.BD.9C.E3.82.92.E3.82.B5.E3.83.9D.E3.83.BC.E3.83.88)

これかぁ！


## 他の書き方
他には TArray\<T\> を使う書き方があります。

```pascal:
procedure Test;
begin
  var arr: TArray<Integer>;
  ...

end;
```

初期化したいのなら配列コンストラクタが使えます。

```pascal:
procedure Test;
begin
var arr := TArray<Integer>.Create(1, 2);
  ...

end;
```


または System.Types を **uses** して、TIntegerDynArray を使うかです。

```pascal:
uses
  ..., System.Types;

...

procedure Test;
begin
  var arr: TIntegerDynArray;
  ...

end;
```

System.Types には T???DynArray という名前で以下のような動的配列の型が定義されています。

| 配列型 | 要素の型 |
|:---|:---:|
| TShortIntDynArray　|ShortInt|
| TByteDynArray|Byte|
| TSmallIntDynArray|SmallInt|
| TWordDynArray|Word|
| TIntegerDynArray|Integer|
| TCardinalDynArray|Cardinal|
| TInt64DynArray|Int64|
| TUInt64DynArray|UInt64|
| TSingleDynArray　|Single|
| TDoubleDynArray|Double|
| TBooleanDynArray|Boolean|
| TStringDynArray|string|
| TWideStringDynArray|WideString|

これらを使ってもいいですね。

## 多次元配列は？
これがですね。

```pascal:
procedure Test;
begin
  var arr := [1, 2][3,4];     // NG
  var arr := [1, 2], [3,4];   // NG
  var arr := [[1, 2], [3,4]]; // NG
  ...

end;
```
どの書き方でもダメなんです。どこかに以下のように定義しておき、

```pascal:
type
  TArray2D<T> = array of array of T;
  TArray3D<T> = array of array of array of T;
```

こんな感じで使うしかないのでしょうね。~~何故これらの定義が最初から用意されていないのだろう？~~

```pascal:
procedure Test;
begin
  var arr: TArray2D<Integer>;
  ...

end;
```

あ！TArray<T> を入れ子で使えという事か。

```pascal:
procedure Test;
begin
  var arr2d: TArray<TArray<Integer>>;         // 2D
  var arr3d: TArray<TArray<TArray<Integer>>>; // 3D
  ...

end;
```

他にいい方法があったら教えて偉い人！

# おわりに
いずれにせよ、インライン変数宣言では静的配列は宣言できないようです。

この制限の理由は大体想像がつきます。Pascal は結果の型 (戻り値の型) に単純型かポインタ型しか使えず、Delphi だと結果の型に構造化型を使うためには型の定義が必要だからでしょう。

 - [11.2. 関数 (Functions)](./b93ac03bfee002f17137.md#112-%E9%96%A2%E6%95%B0-functions)

あるいは型推論がなければインライン変数宣言で静的配列の宣言ができたのかもしれませんが。