TDBGrid で使われている機能ですから、相当古い Delphi でも普通にできます。

[uGridEx.pas]

unit uGridEx;

interface

uses
  Classes, Grids;

type
  TEditBtnClick     = procedure(Sender: TObject; ACol, ARow: Integer) of object;
  TGetPickListItems = procedure(Sender: TObject; ACol, ARow: Integer; Items: TStrings) of object;
  TGetEditStyle     = procedure(Sender: TObject; ACol, ARow: Integer; var EditStyle: TEditStyle) of object;

  TStringGridEx = class(TStringGrid)
  private
    FOnEditBtnClick: TEditBtnClick;
    FOnGetPickListItems: TGetPickListItems;
    FOnGetEditStyle: TGetEditStyle;
    procedure EditButtonClick(Sender: TObject);
    procedure GetPickListItems(ACol, ARow: Integer; Items: TStrings);
  protected
    function CreateEditor: TInplaceEdit; override;
    function GetEditStyle(ACol, ARow: Integer): TEditStyle; override;
  published
    property OnEditBtnClick: TEditBtnClick read FOnEditBtnClick write FOnEditBtnClick;
    property OnGetPickListItems: TGetPickListItems read FOnGetPickListItems write FOnGetPickListItems;
    property OnGetEditStyle: TGetEditStyle read FOnGetEditStyle write FOnGetEditStyle;
  end;

implementation

{ TStringGridEx }

function TStringGridEx.CreateEditor: TInplaceEdit;
begin
  result := TInplaceEditList.Create(Self);
  TInplaceEditList(result).OnGetPickListItems := Self.GetPickListItems;
  TInplaceEditList(result).OnEditButtonClick  := Self.EditButtonClick;
end;

procedure TStringGridEx.EditButtonClick(Sender: TObject);
begin
  if Assigned(FOnEditBtnClick) then
    FOnEditBtnClick(Self, Self.Col, Self.Row);
end;

function TStringGridEx.GetEditStyle(ACol, ARow: Integer): TEditStyle;
var
  LEditStyle: TEditStyle;
begin
  LEditStyle := esSimple;
  if Assigned(FOnGetEditStyle) then
    FOnGetEditStyle(Self, ACol, ARow, LEditStyle);
  result := LEditStyle;
end;

procedure TStringGridEx.GetPickListItems(ACol, ARow: Integer;
  Items: TStrings);
begin
  Items.Clear;
  if Assigned(FOnGetPickListItems) then
    FOnGetPickListItems(Self, ACol, ARow, Items);
end;

end.

　
こんな感じのユニットを作っておけば、

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Grids, uGridEx;

type
  TStringGrid = class(TStringGridEx);

  TForm1 = class(TForm)
    StringGrid1: TStringGrid;
    procedure FormShow(Sender: TObject);
    procedure EditBtnClick(Sender: TObject; ACol, ARow: Integer);
    procedure GetEditStyle(Sender: TObject; ACol, ARow: Integer; var EditStyle: TEditStyle);
    procedure GetPickListItems(Sender: TObject; ACol, ARow: Integer; Items: TStrings);
  private
    { Private 宣言 }
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TForm1 }

procedure TForm1.FormShow(Sender: TObject);
// フォーム表示時
begin
  OnShow := nil;

  StringGrid1.Options := [goFixedVertLine,goFixedHorzLine,goVertLine,goHorzLine,goRangeSelect,goEditing,goAlwaysShowEditor];

  // イベントハンドラを設定
  StringGrid1.OnEditBtnClick     := EditBtnClick;
  StringGrid1.OnGetEditStyle     := GetEditStyle;
  StringGrid1.OnGetPickListItems := GetPickListItems;
end;

procedure TForm1.EditBtnClick(Sender: TObject; ACol, ARow: Integer);
begin
  // グリッドの [...] ボタンが押された時
  ShowMessage(IntToStr(ACol));
end;

procedure TForm1.GetEditStyle(Sender: TObject; ACol, ARow: Integer;
  var EditStyle: TEditStyle);
begin
  // グリッドのセルの種類を設定
  case ACol of
    2: EditStyle := esEllipsis; // [...] ボタン
    3: EditStyle := esPickList; // コンボボックス
  else
    EditStyle := esSimple;
  end;
end;

procedure TForm1.GetPickListItems(Sender: TObject; ACol, ARow: Integer;
  Items: TStrings);
begin
  // コンボボックスのリストを設定
  Items.Add('AAA');
  Items.Add('BBB');
  Items.Add('CCC');
end;

end.

　
こんな感じで使えます。現在作っているものとはちょっとやり方が異なりますが、基本的には同じようなものです。

※ 画像の開発環境は Delphi 7 です。

ほぼ完成。コンポーネントエディタもできており、パッケージの分離も行ってある。

[テーマなし]

[テーマあり]

[VCL スタイル (Carbon)]

後は "現状で使っていない機能" を整備するかどうかだな。

とりあえず完成。すべてを同時に見せる事はできないけれど、先日来からの機能を使うと以下のような表現が可能になる。

機能は増えているけれど、コード量は元の 2/3 になった。今回の作業は確かに面倒だったけれど、意味も解らずに追加した香ばしいコードを一掃できてよかったのかもしれない。"秘伝のタレ" 的なコードは確かに動作するのだけれど、今となっては必要のない Win9x 用コードや Delphi のバグ回避のためのバッドノウハウなコードが無駄に書かれている事が多いので。

XE2 以降用という事になっていますが、(TStrinGrid の) DrawingStyle プロパティが追加された Delphi 2010 以降で動作するように作られています。
(2010 / XE 用のパッケージも一応作って動作確認してあります)

…あとは実戦投入して細部を煮詰めるだけかな。

引用 Mr.XRAY on 2013/06/14 08:55 Fri
でも，この拡張した TStringGrid の説明と図があるだけでも，自分でも作ってみようと考えている方の参考になるのではないかと思います．
結構，動作仕様等の決定も試行錯誤がありますから．
それにしても謎全さんのコンポはすごいですよね．今現在なら中古の在庫まだ数点ありますね．

　
仕様的なものはこちらになります。

[TAltCombogrid 取扱説明書]
http://ht-deko.minim.ne.jp/delphiforum/wp-content/uploads/taltcombogrid.pdf

TStringList を改変する際の参考になるかもしれません。

TAltComboGrid は TComboGrid を置換するために作られているので、プロパティやイベント等を TComboGrid に合わせてあります。コンポーネントエディタなんかはほぼ丸パクリでして、そのせいで "公開しない (できない)" という事だったりします。

本書は著作権法上の保護を受けています。本書の一部あるいは全部について (ソフトウェア及びプログラムを含む)、
株式会社アスキーから文書による許諾を得ずに、いかなる方法においても無断で複写、複製することは禁じられています。

　
"Delphi 2.0J コンポーネントセット" には上記の一文があるのです。

補足ですが、Delphi 3 以降では TStringGrid に OnGetEditMask イベントがあり、このイベント内でインプレースエディタのマスク文字列を指定できます。下記コードは 2 列目に日付用のマスク文字列を指定します。

procedure TForm1.StringGrid1GetEditMask(Sender: TObject; ACol,
  ARow: Integer; var Value: String);
begin
  case ACol of
    1: Value := '!9999/99/00;1; ';
  end;
end;

　
TComboGrid が作成された時点 (Delphi 2) ではこのイベントは存在しなかったのです。

See Also:
[Vcl.Grids.TDrawGrid.OnGetEditMask (DocWiki)]
http://docwiki.embarcadero.com/Libraries/ja/Vcl.Grids.TDrawGrid.OnGetEditMask