使うのはGetDC、SetPixel、ReleaseDCだけです。 再描画されればそこに描いた線は消えます。

procedure TForm1.FormCreate(Sender: TObject);
var 
  DC: THandle; {デバイスコンテキストハンドル}
  i: integer;
begin
  DC := GetDC(0);
  for i:=1 to 800 do 
    SetPixel(DC, i, i, 255);
  //必ず解放
  ReleaseDC(0, DC);
end;

引用 Mr.XRAY on 2013/05/05 18:06 Sun
これを矢印本体だけを描画して，周囲を透明 (透過) したいと思うのですが，
どんな方法があるでしょうか ?

DI_NORMALにするだけかと思ったら、駄目なんですね…
フォーカスを描画するとちゃんと描画されるようですので、無駄な行を追加しました。
理由は聞かれても、未熟者ゆえ、分かりません。
変更箇所は下線部です。

procedure TForm1.Button1Click(Sender: TObject);
var
  hDesktopDC : HDC;
  hCur       : HCURSOR;
  rc: TRect;
begin

  hDesktopDC := GetDC(0);
  GetWindowRect(GetDeskTopWindow, rc);
  rc.Inflate(1, 1); // 陰でこっそり
  DrawFocusRect(hDesktopDC, rc);
  DrawFocusRect(hDesktopDC, rc);
  try
    hCur := LoadCursor(0, IDC_ARROW);
    DrawIconEx(hDesktopDC,
               30,
               530,
               hCur,
               0,
               0,
               0,
               0,
               DI_DEFAULTSIZE or DI_NORMAL);  // 変更
  finally
    ReleaseDC(0, hDesktopDC);
  end;
end;

では私はインチキな方法を。

procedure TForm1.Button1Click(Sender: TObject);
var
  hDesktopDC: HDC;
  BitMap: TBitmap;
  bf: BLENDFUNCTION;
begin
  hDesktopDC := GetDC(GetDesktopWindow);
  BitMap := TBitmap.Create;
  try
    Bitmap.LoadFromFile('C:\aero_arrow.bmp');
    with bf do
      begin
        BlendOp             := AC_SRC_OVER;
        BlendFlags          := 0;
        SourceConstantAlpha := $FF;
        AlphaFormat         := AC_SRC_ALPHA;
      end;
    Windows.AlphaBlend(hDesktopDC, 30, 530, 32, 32, Bitmap.Canvas.Handle, 0, 0, 32, 32, bf);
//  Winapi.Windows.AlphaBlend(hDesktopDC, 30, 530, 32, 32, Bitmap.Canvas.Handle, 0, 0, 32, 32, bf); // XE2 or later
  finally
    Bitmap.Free;
    ReleaseDC(GetDesktopWindow, hDesktopDC);
  end;
end;

　
C:\aero_arrow.bmp は、C:\Windows\Cursors\aero_arrow.cur を 32bit Bitmap に変換したものです。

See Also:
[Alphablend API]
http://msdn.microsoft.com/ja-jp/library/cc428300.aspx

[BLENDFUNCTION 構造体]
http://msdn.microsoft.com/en-us/library/windows/desktop/dd183393%28v=vs.85%29.aspx

ありがとうございます．動作報告です．

Nov さんの方のコードは，Inflate が Delphi XE2 以降のようでしたので，
DEKO さんのコードも両方，Delphi XE2 で確認しました．
DEKO さんの方は，aero_arrow_xl.cur を 32 ビットのビットマップに変換してテストしました．

コードは，そのままコピペして実行しました．ばっちりです．
でも，しかし，Nov さんのこんな簡単なコードで．
また，AlphaBlend という関数があるのをすっかり忘れていました．

う～む．まだまだ勉強不足を実感しました．
サンプルプログラム集の関係あるコードも，機会をみつけて追加または修正します．

で，嬉しいので画像も載せます．
質問の文章内のリンクのブログにも教えたいと思います．ご了承ください．

引用 Nov on 2013/05/06 12:30 Mon
指定した矩形範囲の外側は、直前のFocusRectの背景が使われているような気がします。

　
不思議な仕様 (?) ですよね。

procedure TForm1.Button1Click(Sender: TObject);
var
  hDesktopDC: HDC;
  hCur: HCURSOR;
  rc: TRect;
begin
  hDesktopDC := GetDC(0);
  GetWindowRect(GetDeskTopWindow, rc);
  InflateRect(rc, 1, 1); // 陰でこっそり
  DrawFocusRect(hDesktopDC, rc);
  try
    hCur := LoadCursor(0, IDC_ARROW);
    DrawIconEx(hDesktopDC,
               30,
               530,
               hCur,
               0,
               0,
               0,
               0,
               DI_DEFAULTSIZE or DI_NORMAL);  // 変更
  finally
    DestroyCursor(hCur);
    ReleaseDC(0, hDesktopDC);
  end;
end;

　
補足 (蛇足) ですが TRect.Inflate を API で書き直すとこうなります。

See Also:
[InflateRect API]
http://msdn.microsoft.com/ja-jp/library/cc410418.aspx